Excel如果if函數有多個條件，應該怎么使用（excel中if函數怎么寫多個條件）

Excel中的if函數，如果需要滿足多個條件，那么應該怎么使用if函數，怎么填寫呢？

if函數是 Excel 中的條件判斷函數，它由條件與兩個返回結果組成，當條件成立時，返回真，否則返回假。if函數中的條件既可以單條件，也可以是多條件；多條件組合有三種方式，一種為多個 if 嵌套，第二種為用 And（或 *）組合多個條件，第三種為用 Or（或 +）組合多個條件。用 And（或 *）組合條件是“與”的關系，用 Or(或 +）組合條件是“或”的關系，它們的寫法比 if 嵌套簡單。以下就是它們的具體操作方法。

Excel if函數語法

1

一、Excel if函數語法1、表達式：IF（logical_test,[value_if_true],[value_if_false])中文表達式：如果（條件，條件為真時執行的操作，條件為假時執行的操作）2、說明：[value_if_true] 和 [value_if_false] 表示可選項，即它們可以不寫，如圖1所示：

2

按回車，返回 False，因為 E2 為 435，F2 為 528，E2 > F2 不成立，如圖2所示：圖2

3

另外，=IF(3 > 2,)，返回 0，此處 0 表示假。

Excel if函數單條件使用方法

1

一個服裝銷量表中，價格為0的表示已下架，否則表示正在出售，假如要把它們分別用“下架”和“出售中”標識出來，操作過程步驟，如圖3所示

2

操作過程步驟說明：

選中 H2 單元格，輸入公式 =IF(E2<=0,"下架","出售中")，按回車，則返回“出售中”；把鼠標移到 H2 右下角的單元格填充柄上，按住左鍵并往下拖，則所經過單元格全填充為“出售中”，按 Ctrl + S 保存，則價格為 0 的單元格用“下架”填充，其它單元格用“出售中”填充。

公式說明：公式 =IF(E2<=0,"下架","出售中") 中，E2<=0 為條件，當條件為真時，返回“下架”，否同返回“出售中”。

Excel if函數嵌套多條件使用方法

1

假如要標出服裝銷量表中，“大類”為“女裝”、“價格”大于等于 80 且“銷量”大于 800 的服裝，操作過程步驟，如圖4所示

2

操作過程步驟說明：

選中 H2 單元格，把公式 =IF(C2="女裝",IF(E2>=80,IF(F2>800,"滿足條件","不滿足條件"),"不滿足條件"),"不滿足條件") 復制到 H2，按回車，則返回“不滿足條件”；再次選中 H2，把鼠標移到 H2 的單元格填充柄上，按住左鍵并往下拖，則所經過單元格用“不滿足條件”填充，按 Ctrl + S 保存，同樣 H3 用“滿足條件”填充，其它單元格仍用“不滿足條件”填充。

3

公式說明：

=IF(C2="女裝",IF(E2>=80,IF(F2>800,"滿足條件","不滿足條件"),"不滿足條件"),"不滿足條件")

由三個 if 組成，即在一個 if 中嵌套了兩個 if。第一個 if 的條件為 C2="女裝"，如果條件為真，則執行 IF(E2>=80,IF(F2>800,"滿足條件","不滿足條件"),"不滿足條件")；否則返回“不滿足條件”。第二個 if 的條件為 E2>=80，如果條件為真，則執行 IF(F2>800,"滿足條件","不滿足條件")，否則返回“不滿足條件”。第三個 if 的條件為 F2>800，如果條件為真，返回“滿足條件”，否則返回“不滿足條件”

提示：

if 最多只能嵌套 64 個 if，盡管如此，在寫公式過程中，盡量少嵌套 if；

一方面便于閱讀與修改，另一方面執行效率也高一些。

Excel if函數用 And 與 OR 組合多個條件使用方法

1

用 And 組合多個條件，為“與”的關系

把上例中的多 if 嵌套公式 =IF(C2="女裝",IF(E2>=80,IF(F2>800,"滿足條件","不滿足條件"),"不滿足條件"),"不滿足條件") 改為用 And 組合，操作過程步驟，如圖5所示：

2

操作過程步驟說明：

選中 H2 單元格，把公式 =IF(AND(C2="女裝",E2>=80,F2>800),"滿足條件","不滿足條件") 復制到 H2，按回車，則返回“不滿足條件”；

同樣往下拖并保存，返回跟上例一樣的結果，說明公式正確。

3

公式說明：

=IF(AND(C2="女裝",E2>=80,F2>800),"滿足條件","不滿足條件")

公式用 And 函數組合了三個條件，分別為 C2="女裝",E2>=80,F2>800，當同時滿足三個條件時（即 AND(C2="女裝",E2>=80,F2>800) 返回“真”），返回“滿足條件”，否則返回“不滿足條件”。

4

用 * 代替 And

A、把公式

=IF(AND(C2="女裝",E2>=80,F2>800),"滿足條件","不滿足條件")

用 * 代替 And 后變為：

=IF((C2="女裝")*(E2>=80)*(F2>800),"滿足條件","不滿足條件")

B、按回車，返回“不滿足條件”，往下拖保存后，也是返回一樣的結果。

5

用 Or 組合多個條件，為“或”的關系

1、把上例中的 And 組合多個條件公式 =IF(AND(C2="女裝",E2>=80,F2>800),"滿足條件","不滿足條件") ?改為用 Or 組合，操作過程步驟，如圖

6

2、操作過程步驟說明：選中 H2 單元格，把公式 =IF(OR(C2="女裝",E2>=80,F2>800),"滿足條件","不滿足條件") 復制到 H2，按回車，則返回“滿足條件”；同樣往下拖并保存，全部返回“滿足條件”。

3、公式說明：

=IF(OR(C2="女裝",E2>=80,F2>800),"滿足條件","不滿足條件")

公式用 Or 函數組合了三個條件，分別為 C2="女裝",E2>=80,F2>800，即 OR(C2="女裝",E2>=80,F2>800)，

意思是：只要滿足一個條件，就返回“真”；一條件都不滿足才返回“假”。演示中，每條記錄都滿足一個條件，所以全返回“滿足條件”。

7

4、用 + 代替 Or

A、把公式

=IF(OR(C2="女裝",E2>=80,F2>800),"滿足條件","不滿足條件")

用 + 代替 Or 后變為：

=IF((C2="女裝")+(E2>=80)+(F2>800),"滿足條件","不滿足條件")

如圖8所示：

8

B、按回車，返回“滿足條件”，往下拖保存后，也是全部返回“滿足條件”，說明公式正確。

版權聲明：本文內容由網絡用戶投稿，版權歸原作者所有，本站不擁有其著作權，亦不承擔相應法律責任。如果您發現本站中有涉嫌抄襲或描述失實的內容，請聯系我們jiasou666@gmail.com 處理，核實后本網站將在24小時內刪除侵權內容。

版權聲明：本文內容由網絡用戶投稿，版權歸原作者所有，本站不擁有其著作權，亦不承擔相應法律責任。如果您發現本站中有涉嫌抄襲或描述失實的內容，請聯系我們jiasou666@gmail.com 處理，核實后本網站將在24小時內刪除侵權內容。