Excel用AverageIfs函數求滿足兩個以上條件平均值的6個實例，包含除數為0、不計空單元格與同列多條件

在 excel 中，AverageIfs函數用于滿足兩個或以上的多條件求平均值，而AverageIf函數只用于一個條件求平均值。AverageIfs函數至少要有一個條件，最多不能超 127 個條件，條件之間是“與”的關系；另外，它是 excel 2007 新增加的函數，只能在 Excel 2007 以上版本使用。

用AverageIfs函數多條件求平均值常會遇到除數為 0 錯誤，空單元格的處理，邏輯值的有效與忽略，條件中有表達、函數和通配符問號 ? 與星號 *，條件區域與求平均值區域形狀與大小必須相同，同列多條件求平均值等問題，這些問題以下都配有具體的實例或詳細說明。

一、Excel AverageIfs函數的語法

1、表達式：AVERAGEIFS(Average_Range, Criteria_Range1, Criteria1, [Criteria_Range2, Criteria2], ...)

中文表達式：AVERAGEIFS(求平均值區域, 條件區域1, 條件1, [條件區域2, 條件2], ...)

2、說明：

A、條件區域1與條件1組成一個條件區域/條件對，AverageIfs函數最多不能超過 127 個條件區域/條件對。

B、如果 Average_Range 全為空值、文本值或無法轉為數值的單元格，AverageIfs函數將返回除數為 0 錯誤 #DIV/0!；如果沒有滿足條件的單元格，AverageIfs函數也返回 #DIV/0! 錯誤。

C、條件區域中的空單元格，AverageIfs函數將其視為 0 值。若區域中包含邏輯值 True 或 False，True 被轉為 1、False 被轉為 0。

D、Criteria 可以是數字、文字（如“合格”）、表達式（如 ">=1" 或 ">="&1）和單元格引用。另外，在條件中還可以使用通配符問號（?）和星號（*），問號表示任意一個字符，星號表示一個或一串字符，如果要查找問號或星號，需要在它們前面加轉義字符 ~，例如 ~?、~*。

E、AverageIfs函數要求每個 Criteria_Rang 的大小和形狀必須與 Average_Range 相同，而 AverageIf函數可以不相同。例如：Criteria_Rang 為 A2:A100，Average_Range 為 B2:B100，則為它們的大小與形狀相同；如果 Average_Range 為 B3:B100，則為它們的大小和形狀不相同。

二、Excel AverageIfs函數的使用方法及實例

（一）求滿足兩個條件的平均值實例

1、假如要求在深圳銷售的襯衫的平均銷量。雙擊 F13 單元格，把公式 =AVERAGEIFS(F2:F12,C2:C12,"襯衫",D2:D12,"深圳") 復制到 F13，按回車，返回求平均值結果 525.5；操作過程步驟，如圖1所示：

圖1

2、公式 =AVERAGEIFS(F2:F12,C2:C12,"襯衫",D2:D12,"深圳") 說明：

F2:F12 為求平均值區域；C2:C12 為第一個條件區域，"襯衫" 為第一個條件；D2:D12 為第二個條件區域，"深圳" 為第二個條件；公式的意思是：在 C2:C12 中查找所有為“襯衫”的服裝，再在 D2:D12 中查找所有為“深圳”的服裝，然后在 F2:F12 中，求滿足兩個條件的平均值。

（二）返回除數為 0 錯誤 #DIV/0! 的實例

1、雙擊 A8 單元格，把公式 =AVERAGEIFS(A2:A7,C2:C7,">=5") 復制到 A8，按回車，返回除數為 0 錯誤 #DIV/0!；再雙擊 D8，把公式=AVERAGEIFS(D2:D7,C2:C7,">=20") 復制到 D8，按回車，也返回除為 0 錯誤；操作過程步驟，如圖2所示：

圖2

2、公式 =AVERAGEIFS(A2:A7,C2:C7,">=5") 的求平均值區域為 A2:A7，盡管 C2:C7 中有滿足條件的記錄，但 A2:A7 中全為文本，因此返回除數為 0 錯誤。公式 =AVERAGEIFS(D2:D7,C2:C7,">=20") 中，D2:D7 全為數值，但 C2:C7 沒有滿足條件的記錄，所以也返回除數為 0 錯誤。

（三）邏輯值 True 或 False 有效與忽略的實例

1、雙擊 A7 單元格，把公式 =AVERAGEIFS(A1:A6,B1:B6,TRUE) 復制到 A7，按回車，返回求平均值結果 6；操作過程步驟，如圖3所示：

圖3

2、公式 =AVERAGEIFS(A1:A6,B1:B6,TRUE) 在 A1:A6 中求平均值，條件是 B1:B6 中的值為 TRUE，滿足條件的只有 B1、B3 和 B6，A2，A3 和 A6 中的值分別為 TRUE，FALSE 和 TRUE，而求平均值結果為 6，說明 A2，A3 和 A6 沒有計入求平均值，即邏輯值在求平均值區域被忽略；而在 B1:B6 中能選出為 TRUE 的記錄，說明邏輯值在條件區域有效。

（四）條件中使用通配符 ? 或 * 的實例

1、假如要求“編號”以 NS 開頭且“產品名稱”僅有四個字的服裝平均銷量。雙擊 F13 單元格，把公式 =AVERAGEIFS(F2:F12,A2:A12,"NS*",B2:B12,"????") 復制到 F13，按回車，返回求平均值結果 679.33；操作過程步驟，如圖4所示：

圖4

2、公式 =AVERAGEIFS(F2:F12,A2:A12,"NS*",B2:B12,"????") 說明：

F2:F12 為求平均值區域；A2:A12,"NS*" 為第一個條件區域/條件對，意思是在 A2 至 A12 中找出所有以 NS 開頭的服裝，NS 后的 * 表示任意一個或多個字符；B2:B12,"????" 為第二個條件區域/條件對，意思是在 B2:B12 中找出所有僅有四個字的服裝；執行時，先找出滿足第一個條件的服裝，然后把找出的服裝再匹配第二個條件，最后返回符合兩個條件的服裝，再在 F 列求這些服裝的平均值。

（五）同一區域同時為求平均值和條件區域的實例

1、假如要求所有銷量大于 0 的女裝平均銷量。雙擊 D9 單元格，把公式 =AVERAGEIFS(E2:E8,C2:C8,"女裝",E2:E8,">0") 復制到 E9，按回車，返回求平均值結果 627.75；操作過程步驟，如圖5所示：

圖5

2、公式中的 E2:E8 既為求平均值區域又為第二個條件 ">0" 的區域，說明同一區域可同時為求平均值和條件區域。

提示：如果求平均值區域有空單元格又不想把它計入求平均值，可以用條件 ">0" 排除。

（六）同列多條件求平均值實例

1、假如要求價格在 100 到 200 之間服裝銷量的平均值。雙擊 E13 單元格，把公式 =AVERAGEIFS(E2:E12,D2:D12,">=100",D2:D12,"<=200") 復制到 E13，按回車，返回求平均值結果 730；操作過程步驟，如圖6所示：

圖6

2、公式 =AVERAGEIFS(E2:E12,D2:D12,">=100",D2:D12,"<=200") 的條件區域都為 D2:D12，意思是在 D2:D12 中找出同時滿足大于等于 100 與小于等于 200 的所有服裝，然后在 E 列求它們的平均值。

（七）兩個條件為日期的求平均值實例

1、假如要求在 2018年9月10和11日兩天銷售的服裝的平均銷量。雙擊 D12 單元格，把公式 =AVERAGEIFS(D2:D11,B2:B11,">=2018/9/10",B2:B11,"<=2018/9/11") 復制到 D12，按回車，返回求平均值結果 805；操作過程步驟，如圖7所示：

圖7

2、公式 =AVERAGEIFS(D2:D11,B2:B11,">=2018/9/10",B2:B11,"<=2018/9/11") 的條件區域都為 B2:B11；從第一個條件 ">=2018/9/10" 可知：當日期與大于等于組成合時，可以把它們寫在一起；公式的意思是在 B2:B11 中找出同時滿足大于等于 "2018/9/10" 與小于等于 "2018/9/11" 的所有服裝，然后在 D 列求它們的平均銷量。

版權聲明：本文內容由網絡用戶投稿，版權歸原作者所有，本站不擁有其著作權，亦不承擔相應法律責任。如果您發現本站中有涉嫌抄襲或描述失實的內容，請聯系我們jiasou666@gmail.com 處理，核實后本網站將在24小時內刪除侵權內容。

版權聲明：本文內容由網絡用戶投稿，版權歸原作者所有，本站不擁有其著作權，亦不承擔相應法律責任。如果您發現本站中有涉嫌抄襲或描述失實的內容，請聯系我們jiasou666@gmail.com 處理，核實后本網站將在24小時內刪除侵權內容。