Excel Left函數和LeftB函數使用方法的9個實例，含倒數提取、數值帶單位求和及與If、Find組合

在 Excel 中，Left函數用于從文本中提取從左邊第一個字符開始的指定字符數，而LeftB函數用于從文本中提取從左邊第一個字符開始的指定字節數；它們的區別為：前者提取字符數，即把全角和半角都計作一個字符；后者提取字節數，即把全角計作兩個字節、半角計作一個字節。

在實際應用中，Left函數和LeftB函數常與 If、Len、LenB、Find、Sum、Value 和 Match 等函數組合使用，例如 Left + Len（或 LeftB + LenB）組合實現倒數提取字符，If + Find 組合實現返回符合條件的查找內容，Left + Find 組合實現自動計算要提取的字符數，Sum + Value + Left 組合實現數值帶單位求和。

一、Excel Left函數和LeftB函數的語法

1、Left函數表達式：LEFT(Text, [Num_Chars])

中文表達式：LEFT(文本, 提取字符數)

2、LeftB函數表達式：LEFTB(Text, [Num_Bytes])

中文表達式：LEFTB(文本, 提取字節數)

3、說明：

A、Left函數把全角（如漢字）和半角字符（如數字與字母）都計作一個字符，LeftB函數把全角字符計作兩個字節、半角字符計作一個字節。

B、Num_Chars 為要提取字符數，它必須大于或等于 0，否則將返回值錯誤 #VALUE!；如果 Num_Chars 大于文本長度，將返回所有文本；如果省略 Num_Chars，則默認取 1。

C、Num_Bytes 為要提取字符的字節數，它必須大于或等于 0，否則也將返回值錯誤 #VALUE!；如果 Num_Bytes 大于文本長度的一倍或兩倍（半角字符大于一倍，全角字符大于兩倍），將返回所有文本；如果省略 Num_Bytes，則默認取 1。

二、Excel Left函數的使用方法及實例

（一）提取左邊的數字實例

1、假如要提取單位左邊的數字。雙擊 B1 單元格，輸入公式 =LEFT(A1,3)，按回車，返回 2.5；選中 B1，把鼠標移到 B1 右下角的單元格填充柄上，鼠標變為加號后，雙擊左鍵，則返回剩余單位前的數字；操作過程步驟，如圖1所示：

圖1

2、公式 =LEFT(A1,3) 中，A1 為要提取數字的文本，3 為提取字符數；公式的意思是，把 A1 中的“2.5升/瓶”從第一個字符開始提取且只提取 3 個字符。

（二）提取一個字符和所有文本的實例

1、雙擊 A8 單元格，輸入公式 =LEFT(A3,)，按回車，返回“空”；雙擊 A8，把逗號去掉，按回車，返回“青”字；再次雙擊 A8，在 A3 后輸入“,6”，按回車，返回“青皮西瓜”；操作過程步驟，如圖2所示：

圖2

2、公式說明：

A、公式 =LEFT(A3,) 返回空，而公式 =LEFT(A3) 返回“青”，說明省略提取字符數參數時，不能有逗號；另外，省略“提取字符數”時，它的值默認取 1。

B、公式 =LEFT(A3,6) 從第一個字符開始返回 6 個字符，由于 A3 中只有 4 個字符，因此只返回到文本末尾，即返回所有字符。

（三）提取字符數小于 0，返回 #VALUE! 錯誤實例

1、雙擊 B1 單元格，把公式 =LEFT(A1,-1) 復制到 B1，按回車，返回值錯誤 #VALUE!；雙擊 B1，把 -1 改為 1，按回車，返回 2；再次雙擊 B1，把 1 改為 0，按回車，返回“空”；操作過程步驟，如圖3所示：

圖3

2、公式 =LEFT(A1,-1) 返回錯誤，是因為第二個參數“提取字符數”必須大于等于 0；公式 =LEFT(A1,1) 返回 A1 中的第一個字符 2；公式 =LEFT(A1,0) 由于“提取字符數”為 0，因此返回“空”。

三、Excel LeftB函數的使用方法及實例

（一）提取數字和字母的實例

1、假如要從 A 列中提取重量和單位。雙擊 B1 單元格，輸入公式 =LEFTB(A1,3)，按回車，返回 3Kg；把鼠標移到 B1 右下角的單元格填充柄上，然后雙擊，提取出剩余單元格的重量和單位；操作過程步驟，如圖4所示：

圖4

2、公式 =LEFTB(A1,3) 中，A1 為要提取字符的文本，3 為要提取的字節數；公式的意思是，從 A1 中的“3Kg蘋果”中第一個字符開始提取 3 個字節，即提取 3Kg；從返回結果可知，LeftB函數與Left函數一樣，都把數字和字母計作一個字節。

（二）提取漢字的實例

1、假如要從“蘋果12￥/Kg”中提取“蘋果”二字。雙擊 B1 單元格，把公式 =LEFTB(A1,4) 復制到 B1，按回車，返回提取結果“蘋果”；雙擊 B1，把 4 改為 3，按回車，只返回“蘋”字；操作過程步驟，如圖5所示：

圖5

2、公式 =LEFTB(A1,4) 從 A1 中提取 4 個字節，返回結果只有“蘋果”二字，說明 LeftB 把每個漢字計作兩個字節；則公式 =LEFTB(A1,3) 只返回“蘋”一字，說明提取漢字時，單個字節被忽略，因為一個字節不能組成一個漢字。

四、Excel Left函數和LeftB函數的應用實例

（一）Left + Len函數組合實現倒數提取字符

1、假如要從倒數第 5 位開始提取。雙擊 B2 單元格，把公式 =LEFT(A2,LEN(A2)-5 + 1) 復制到 B2，按回車，返回 A2018；操作過程步驟，如圖6所示：

圖6

2、公式 =LEFT(A2,LEN(A2)-5 + 1) 說明：

A、公式中的 5 為倒數提取的開始位置，即從右往左第 5 個字符開始提取；LEN(A2) 用于返回 A2 的字符數，結果為 9，Len函數把無論是全角字符還是半角字符都計作一個字符。

B、則公式變為 =LEFT(A2,9 - 5 + 1)，進一步計算變為 =LEFT(A2,5)，即從左邊開始提取，共提取 5 個字符，結果為 A2018。

提示：LeftB + LenB 也可以實現同樣功能，公式可以這樣寫：=LEFTB(A2,LENB(A2)-5 + 1)，把公式復制到 B3，按回車，也返回 A2018，操作過程步驟，如圖7所示：

圖7

公式 =LEFTB(A2,LENB(A2)-5 + 1) 中，5 也為倒數提取字符開始的位置，LENB(A2) 返回 A2 的字節數，結果為 9，LenB函數把全角字符計作 2 個字節、半角字符計作 1 個字節，這與 LeftB 相同；則公式變為 =LEFTB(A2,5)，然后從左邊提取 5 個字節的字符。

（二）If + Left函數組合實現返回符合條件的查找內容

1、假如要找出所有“黃”姓員工的“職務”。雙擊 D2 單元格，把公式 =IF(LEFT(A2)="黃",C2,"") 復制到 D2，按回車，返回空值；選中 D2，用雙擊單元格填充柄的方法找出剩余員工的職務；操作過程步驟，如圖8所示：

圖8

2、公式 =IF(LEFT(A2)="黃",C2,"") 說明：

A、LEFT(A2) 用于截取 A2 中姓名中的“姓”；LEFT(A2)="黃" 是 If 的條件，如果 LEFT(A2) 返回結果等于“黃”，則返回 C2，否則返回空值。

B、當公式在 D2 時，LEFT(A2) 返回“李”，不等于“黃”，所以返回空值；當公式在 D5 時，A2 自動變 A5， LEFT(A5) 返回“黃”，所以返回 C5（即“經理”）。

（三）Left + Find函數組合實現自動計算要提取字符數

1、當要從比較多的文本中提取字符或僅提取到特定字符，可以先用Find函數返回某個字符的位置，再用Left函數提取。假如要提取 A2 中從開始字符到 5 的這一串字符。雙擊 B2 單元格，把公式 =LEFT(A2,FIND(5,A2)) 復制到 B2，按回車，返回 A201809010005；操作過程步驟，如圖9所示：

圖9

2、公式 =LEFT(A2,FIND(5,A2)) 說明：

A、FIND(5,A2) 用于返回 5 在 A2 中的位置（結果返回 13），5 為查找文本，A2 為找查 5 的原文本，FIND(5,A2) 省略了最后一個指定查找開始位置的參數，默認從第一個字符開始查找。

B、則公式變為 =LEFT(A2,13)，最后從左邊第一個字符開始截取 13 字符，即截取得 A201809010005。

（四）Sum + Value + Left函數組合實現數字帶單位的求和

1、如果求和的數值后面帶單位，則無法用Sum函數求和，需要先把數值提取出來再求和。假如要求一個水果表的銷量之和。雙擊 D8 單元格，把公式 =SUM(VALUE(LEFT(D2:D7,4))) 復制到 D8，按 Ctrl + Shift + 回車，返回求和結果 12743；操作過程步驟，如圖10所示：

圖10

2、公式 =SUM(VALUE(LEFT(D2:D7,4))) 說明：

A、公式為數組公式，所以要按 Ctrl + Shift + 回車。D2:D7 以數組形式返回 D2 至 D7 中的值，即{"2685kg";"3500kg";"1258kg";"2050kg";"1050kg";"2200kg"}

B、則 LEFT(D2:D7,4) 變為 則 LEFT({"2685kg";"3500kg";"1258kg";"2050kg";"1050kg";"2200kg"},4)，執行時，第一次取出數組中的第一個元素 "2685kg"，并取截取前四位數字，即 2685；第二次取出數組中的第二個元素，也截取前四位數字，即 3500；其它的以此類推，最后返回 {"2685";"3500";"1258";"2050";"1050";"2200"}。

C、則公式變為 =SUM(VALUE({"2685";"3500";"1258";"2050";"1050";"2200"}))，進一步計算，用Value函數把數組中字符元素轉為數值，則公式變為 =SUM({2685;3500;1258;2050;1050;2200})，最后用Sum函數求和。

版權聲明：本文內容由網絡用戶投稿，版權歸原作者所有，本站不擁有其著作權，亦不承擔相應法律責任。如果您發現本站中有涉嫌抄襲或描述失實的內容，請聯系我們jiasou666@gmail.com 處理，核實后本網站將在24小時內刪除侵權內容。